private var original:BitmapData; // class-level variable
var picBMD:BitmapData;
var alphaMask:BitmapData = null;
var mask:Sprite = new Sprite();
var m:Matrix = new Matrix();
var focusSize:int = hsFocusSize.value;
var focusLoc:int = hsFocusLoc.value;

if (original == null) {
	original = (pic.content as Bitmap).bitmapData.clone();
}
picBMD = original.clone();

picBMD.applyFilter(picBMD, picBMD.rect, picBMD.rect.topLeft, new BlurFilter(5, 5, 3));

m.createGradientBox(picBMD.width, picBMD.height * (focusSize / 100), 90 / (180 / Math.PI), 0, picBMD.height * ((focusLoc - focusSize) / 100));
mask.graphics.beginGradientFill("linear", new Array(0xFFFFFF, 0xFFFFFF, 0xFFFFFF, 0xFFFFFF), new Array(0, 1, 1, 0), new Array(0, 85, 170, 255), m);
mask.graphics.drawRect(0, 0, picBMD.width, picBMD.height);
alphaMask = new BitmapData(picBMD.width, picBMD.height, true, 0xFFFFFF);
alphaMask.draw(mask);

picBMD.copyPixels(original, original.rect, original.rect.topLeft, alphaMask, alphaMask.rect.topLeft, true);

if (chkSaturate.selected) {
	var cm:ColorMatrix = new ColorMatrix();
	cm.adjustSaturation(20);
	picBMD.applyFilter(picBMD, picBMD.rect, picBMD.rect.topLeft, new ColorMatrixFilter(cm));
}

(pic.content as Bitmap).bitmapData = picBMD;

Lines 1–7: Variable declaration. original is a class-level variable that holds the unaltered version of the bitmapData. focusSize is how big an area to focus and focusLoc is where on the y-axis to position the focus. Both of these are percentages.

Lines 9–12: If we haven’t stored the unaltered bitmapData yet, do it now. Clone that data to use in our filter.

Line 14: Normally, the tutorials call for a Lens Blur. We’ll settle for just doing a 5x5 blur on the entire image.

Line 16: Use our matrix to create a gradient box that is the same width as the image and the height as we specified with our focusSize percentage. The 90 / (180 / Math.PI) is just saying that we want our gradient to direct itself vertically at a 90 degree angle (converting 90 degrees to radians). Because the gradient is vertical, we use 0 for tx because it doesn’t matter where we position it horizontally. ty is set to the location specified by focusLoc.

Line 17: Begin our gradient fill in the mask sprite. We have to use a sprite because BitmapData objects don’t have graphics properties. The fill should be linear, white (0xFFFFFF) and transparent on the edges. new Array(0, 85, 170, 255) means that the gradient colors and transparency levels should begin drawing at 0 and change to the next set at 85, where 0–255 is a scale like 0–100%.

Line 18: Draw the gradient onto the sprite.

Lines 19–20: Set up our alphaMask to be the same size as our image and draw the contents of our sprite onto it.

Line 22: This is the actual effect, now. Copy the pixels from the original image, using the transparency mask, onto our blurred image. This will cause the image to go from blurred to clear using the gradient we created.

Lines 24–28: If we’re over-saturating the image, create a new ColorMatrix (), courtesy of Grant Skinner, and adjust the saturation to boost by 20. This will make all of the colors look a little too bright (and fake, like a model). Apply the filter as normal.

Line 30: Set our image to use the filtered BitmapData.

That’s all there is to it. A nice, little effect and not too difficult.